10 POKE646,1:POKE53280,0:POKE53281,0:PRINT"[147]":S$="          ":GOTO40
20 GETJUNK$:IFJUNK$<>""THEN20
30 RETURN
40 PRINT" THIS PROGRAM WILL FORMAT A NEW DISK SO"
50 PRINT"THAT FILES AND PROGRAMS MAY BE STORED"
60 PRINT"UPON IT.  IF THIS PROCESS IS PERFORMED"
70 PRINT"UPON A DISK WHICH IS ALREADY USED FOR"
80 PRINT"SUCH STORAGE, ALL INFORMATION ON THAT"
90 PRINT"DISK WILL BE ERASED."
95 PRINT"  1.  CONTINUE PROGRAM"
96 PRINT"  2.  EXIT TO LOADSTAR"
97 PRINT"WHICH ?";
98 POKE198,0:WAIT198,1:GETA$:IFA$<>"1"ANDA$<>"2"THEN98
99 IFA$="2"THEN63000
100 PRINT:PRINT"REMOVE THE PRESENT DISK FROM THE DRIVE!"
110 GOSUB20
120 PRINT"IS THE DISK DRIVE EMPTY?  (Y/N)"
130 GETA$:IFA$=""GOTO130
140 PRINT"[147]":IFA$<>"Y"GOTO100
150 PRINT"THE NEW DISK SHOULD HAVE A NAME OF LESS"
160 PRINT"THAN 17 CHARACTERS WHICH CANNOT INCLUDE"
170 PRINT"COMMAS AND QUOTATION MARKS."
180 PRINT"TYPE THE NAME OF THE DISK AND THEN PRESSTHE RETURN[146] KEY";
181 B$=""
182 GETA$:IFA$=""GOTO182
183 IFASC(A$)=20THENPRINT"[147]"S$"      RESTART"S$"       ":GOTO150
184 IFASC(A$)=34GOTO205
186 IFASC(A$)=44GOTO205
188 IFASC(A$)=13GOTO192
190 PRINTA$;:B$=B$+A$:GOTO182
192 IFLEN(B$)<17GOTO210
200 PRINT"[147]";B$:PRINT" IS TOO LONG FOR A DISK NAME.":GOTO150
205 PRINT"[147]  ILLEGAL CHARACTER FOLLOWING ";B$;"":GOTO150
209 PRINT"[147]           ILLEGAL  CHARACTER           "
210 PRINT:PRINT"THE NEW DISC NEEDS AN IDENTIFICATION"
220 PRINT"NUMBER OF TWO CHARACTERS WHICH CANNOT"
230 PRINT"INCLUDE COMMAS AND QUOTATION MARKS."
240 C$="":PRINT"TYPE THE IDENTIFICATION NUMBER"
242 GETA$:IFA$=""GOTO242
244 IFASC(A$)=34GOTO209
246 IFASC(A$)=44GOTO209
248 C$=A$:PRINTC$;
250 GETA$:IFA$=""GOTO250
252 IFASC(A$)=34GOTO209
254 IFASC(A$)=44GOTO209
256 PRINTA$
260 C$=C$+A$
270 D$="N0:"+B$+","+C$
300 PRINT"[147]    PLACE THE NEW DISK IN THE DRIVE     [146]"
310 PRINT"ALL INFORMATION PRESENTLY ON THE DISK"
320 PRINT"WHICH IS NOW IN THE DRIVE WILL BE"
330 PRINT"ERASED IF YOU PRESS Y[146]."
340 GOSUB20
350 PRINT"IS THE NEW DISK IN THE DRIVE?  (Y/N)"
360 GETA$:IFA$=""GOTO360
370 IFA$<>"Y"GOTO300
380 PRINT"[147] WAIT 80 SECONDS....FORMATTING THE DISK "
390 OPEN15,8,15,D$
395 INPUT#15,ER,ER$,TR,SE
396 IFER<>0THENGOSUB1000:CLOSE15:GOTO430
400 CLOSE15
410 PRINT"[147]THIS DISK IS READY FOR STORAGE."
420 GOSUB20
430 PRINT"                  MENU                  "
440 PRINT"1[146]  FORMAT ANOTHER DISK WITH SAME NAME      AND ID NUMBER"
450 PRINT"2[146]  FORMAT ANOTHER DISK WITH SAME NAME"
455 PRINT"BUT DIFFERENT ID NUMBER"
460 PRINT"3[146]  FORMAT ANOTHER DISK WITH DIFFERENT"
465 PRINT"NAME AND ID NUMBER"
470 PRINT"4[146]  QUIT THE PROGRAM"
480 GETA$:IFA$=""GOTO480
490 PRINT"[147]":ONVAL(A$)GOTO300,210,100
500 PRINT"[147]PUT THE LOADSTAR DISK BACK IN THE DRIVE."
502 PRINT"          AND PRESS A KEY."
504 POKE198,0:WAIT198,1:GETA$
505 GOTO63000
506 :
1000 PRINT"[147]WE HAVE ENCOUNTERED AN ERROR!"
1010 PRINT"THE ERROR HAS A CODE OF:"ER
1020 PRINT"THE ERROR MESSAGE IS   :"ER$
1030 PRINT"PLEASE TRY AGAIN OR USE ANOTHER DISK."
1040 PRINT""SPC(13)"<PRESS A KEY>"
1050 POKE198,0:WAIT198,1:GETM$:PRINT"[147]";:RETURN
63000 PRINT"[147]LOAD"CHR$(34)"PAYLOAD"CHR$(34)",8":PRINT"RUN"
63010 POKE631,13:POKE632,13:POKE198,2:END